!---------------------------------------------------
! Scene 2: Thuis
!---------------------------------------------------

Object mijnslaap "In je slaapkamer"
  with name 'slaapkamer' 'kamer',
       description "Het zwakke schijnsel van de maan dat door het raam naar binnen valt hult de meubels in de slaapkamer in een mantel van onwereldse schoonheid. Alleen het zachte ademen van je echtgenote in het grote ledikant doorbreekt de stilte. Naast de zware eiken kledingkast bevindt zich de deur naar de overloop in het noorden. In de onverwarmde kamer is het ijzig koud.",
       n_to over_deur,
  has light male transparent;

Object mijnbed "ledikant" mijnslaap
 class Furniture,
  with name 'bed' 'ledikant' 'hemelbed' 'grote',
       description "Het grote, door jou zelf getimmerde bed neemt bijna de halve kamer in beslag. Maanlicht kruipt over de veelkleurige deken, die bij elke ademtocht van je vrouw op en neer gaat.",
       react_before [;
         Sleep: if (parent(player) == self) {
	   "Natuurlijk, als je gewoon weer in slaap kon vallen, niets hoefde te doen en nergens aan hoefde te denken. Maar zo gemakkelijk is het niet. Je zal aan Maartje denken en blijven denken, en niet kunnen slapen tot je tot actie bent overgegaan. En zelfs als het je zou lukken om in slaap te vallen, dan is er morgen weer een dag, en overmorgen - en het zal niet steeds opnieuw blijven lukken. Beter om het kwaad vandaag onder ogen te zien, dan om de confrontatie uit te stellen tot morgen.";
	 };
       ],
  has  enterable transparent scenery;
  
Object deken "deken" mijnbed
 class Prop,
  with name 'deken' 'laken' 'veelkleurige' 'dekbed',
       description "Rode, blauwe en groene vlakken, nauwelijks herkenbaar in het schemerduister, wisselen elkaar schijnbaar zonder patroon af. Je vrouw Hilde heeft de deken zelf op maat bij het door jou vervaardigde bed gemaakt. Jullie hebben de traditie in ere gehouden: pas toen beide gereed waren kon er getrouwd worden.",
       before [;
         Touch: "Zachtjes streel je de deken en denk je aan gelukkiger tijden.";
       ],
   has male;

Object vrouw "Hilde" mijnbed
  with name 'vrouw' 'echtgenote' 'geliefde' 'eega' 'Hilde',
       slaap 0,
       description [;
         if (self.slaap == 0) {
	   self.slaap = 1;"Je buigt je voorover om Hildes gezicht beter te kunnen zien; even stokt haar adem en lijkt ze te verstijven, dan keert het gestadige ritme weer terug. Maar je weet genoeg - ze slaapt niet! Ze weet waar je naar op weg bent, maar houdt zich slapende. Een stille goedkeuring die ze nooit zou kunnen uitspreken? Of is ze simpelweg te bang om de confrontatie aan te gaan?";
	 }
	 else {
	   "Hildes stille engelengezicht en haar regelmatige ademhaling verraden niet dat ze wakker is. Ze weet waar je naar op weg bent, maar houdt zich slapende. Een stille goedkeuring die ze nooit zou kunnen uitspreken? Of is ze simpelweg te bang om de confrontatie aan te gaan?";
	 };
       ],
       before [;
         Answer, Ask, AskFor, Tell, Squeeze, Spreek: if(self.slaap == 0){"Nee, je wilt Hilde niet wakker maken. Zij is er heftig tegen dat je je leven waagt in een poging jullie dochter te bevrijden. Elke keer wanneer je de afgelopen dag ter sprake bracht dat je iets zou gaan doen om haar te redden uit de klauwen van de baron heeft zij geroepen dat ze het niet aan zou kunnen om jou ook nog te verliezen. Beter is het haar te laten slapen en in stilte te vertrekken.";}
	   else {"Het is beter om de fa@ccade in stand te houden. Laat haar doen alsof ze slaapt. Ze weet toch al precies wat je gaat doen, en het is voor haar gemakkelijker te accepteren wanneer ze er niet expliciet mee geconfronteerd wordt. Bovendien wil je zelf liever ook niet over de risico's nadenken.";};
         
	 Attack: "Je balt je vuisten in een plotseling moment van woede. ~Het zou voor eeuwig zijn!,~ flitst er door je hoofd - maar even snel verdwijnt de gedachte weer en begrijp je niet meer wat hij betekende. Je zou nooit je vrouw Hilde aanvallen. Je houdt immers van haar.";
	 
	 Kiss: if(self.slaap == 0){self.slaap = 1;"Je buigt je voorover om Hildes gezicht te kunnen zoenen; even stokt haar adem en lijkt ze te verstijven, dan keert het gestadige ritme weer terug. Maar je weet genoeg - ze slaapt niet! Ze weet waar je naar op weg bent, maar houdt zich slapende. Een stille goedkeuring die ze nooit zou kunnen uitspreken? Of is ze simpelweg te bang om de confrontatie aan te gaan?";}
	   else {"Jouw lippen beroeren haar blanke wang in het tederste teken van afscheid. Vreemd genoeg lijkt zij te verstijven en te proberen haar hoofd verder in het kussen te laten zakken.";};
	 
	 Listen: if(self.slaap == 0){"De ritmische ademhaling van Hilde is een rustgevend geluid in deze gevaarlijke nacht.";}
	   else{"De ritmische ademhaling van Hilde verraadt niet dat ze eigenlijk wakker is.";};
	 
	 Pull, Push: "Je zou nooit hardhandig met je echtgenote omgaan.";
	 
	 Smell: "Haar geur herken je uit duizenden. Het is de geur van warmte en geborgenheid.";
	 
	 Touch, Knuffel: if(self.slaap == 0){"Dat kan je beter niet doen; wellicht wordt ze er wakker van.";}
	   else{"Je laat je vingertoppen even over haar wang en door haar blonde haren spelen. Een korte rilling gaat door haar heen, maar ze blijft bij haar toneelspel en houdt zich slapende.";};
	 
	 WakeOther: if(self.slaap == 0){<<spreek self>>;}
	   else{"Hoe zou je iemand kunnen wekken die niet slaapt?";};
       ],
       orders [;
         	 
	 default: if (self.slaap == 0) {
	     "Je wilt Hilde niet wakker maken. Zelfs als ze je niet zou tegenhouden, zou ze zich alleen maar nodeloos zorgen maken als ze wist welke heldendaden jij vannacht zal volbrengen.";}
	   else {
	     "Hilde reageert niet op je commando.";
	   };
       ],
   has animate female proper scenery;

Object mijn_kussen "kussen" mijnbed
 class Prop,
  with name 'kussen' 'kussens',
       description "Een simpel kussen, gevuld met veren.",
   has ;

Object stoel "stoel" mijnslaap
 class PropSup,
  with name 'stoel' 'kruk' 'zetel',
       description "Een eenvoudige houten stoel die je gebruikt om je kleding 's avonds overheen te hangen.",
       before[;
            Enter:
	     move player to self;
	     "Je zet jezelf op de stoel.";
	    Exit, GetOff:
	     move player to parent(self);
	     "Je staat op.";
	  ],
	  react_before [;
	    Go, Open, Close, Search, Take, Enter, LookUnder, Pull, Push, JumpOver, Attack, Climb, Burn, Dig, Cut, Jump:
	      if(parent(player) == self) {
	        move player to parent(self);
		print "Eerst sta je op.^";
		return false;
	      }
	      return false;
	    
	    Sit: <<Enter self>>;
	    
	    default: return false;
	  ],
   has male enterable supporter transparent scenery static;

   
Object kleding "je werkkleding" stoel
  with name 'kleding' 'kleren' 'werkkleding',
       description "Dit is de kleding waarmee je overdag in het woud hout gaat hakken: een stevige spijkerbroek, een rood-blauw geruit hemd en twee zware leren laarzen. Er hangt een vage zweetgeur om het hemd heen.",
       before [;
         Wear: if(jas has worn && kleding hasnt worn) "Je kan je werkkleding niet over je winterjas heen aantrekken.";
	 Disrobe: if(jas has worn && kleding has worn) 
	             "Je zal eerst de winterjas moeten uittrekken voordat je je werkkleding uit kunt doen.";
	 Burn:
	     if(TestScope(toorts,player)) {
	       if(second == toorts || second == nothing) {
	         if(toorts has general) {
		   if(verhaaltracker.status == 5) {
		       "Hier in deze lege hallen zullen maar weinigen onder de indruk zijn van je zelfverbranding.";
		     } else {
                       ZelfVerbrand();
		     };
		 } else {
		   "Nu de toorts gedoofd is kan je er niets meer mee aansteken.";
		 }
	       } else {
	         "Daarmee kan je niets aansteken.";
	       }
	     }		  
	], 
   has clothing proper transparent;
   
  Object hemd "houthakkershemd" kleding
    with name 'hemd' 'houthakkershemd' 'shirt' 'wollen' 'geruit' 'zweet',
         description "Een rood-blauw geruit wollen hemd, door je vrouw Hilde met de hand gesponnen, geverfd en gebreid. De geur van het eerlijke zweet van de harde werker hangt er omheen.",
	 before [;
	   Wear: <<Wear kleding>>;
	   Take: <<Take kleding>>;
	   Disrobe: <<Disrobe kleding>>;
	   Drop: <<Drop kleding>>;
	   PutOn: <<PutOn kleding second>>;
	   Burn: <<Burn kleding>>;
	   Smell: "Onmiskenbaar een zweetgeur. Maar volgens Hilde is dat juist opwindend.";
	 ],
     has concealed;
     
  Object broek "houthakkersbroek" kleding
    with name 'broek' 'houthakkersbroek' 'stevige' 'spijkerbroek' 'jeans' 'Levi^s' 'jeans',
         description "Blauwe Levi's jeans, niet mooier geworden van wat ze tijdens het uitoefenen van je beroep allemaal hebben moeten doorstaan. Dat ze nog steeds intact zijn is een bewijs van hun duurzaamheid.",
	 before [;
	   Wear: <<Wear kleding>>;
	   Take: <<Take kleding>>;
	   Disrobe: <<Disrobe kleding>>;
	   Drop: <<Drop kleding>>;
	   PutOn: <<PutOn kleding second>>;
	   Burn: <<Burn kleding>>;
	  ],
     has male concealed;

  Object laarzen "houthakkerslaarzen" kleding
    with name 'laars' 'laarzen' 'leren' 'zware' 'houthakkerslaarzen' 'schoenen',    
	 description "Een paar leren laarzen, met stalen neuzen voor extra bescherming.",
	 before [;
	   Wear: <<Wear kleding>>;
	   Take: <<Take kleding>>;
	   Disrobe: <<Disrobe kleding>>;
	   Drop: <<Drop kleding>>;
	   PutOn: <<PutOn kleding second>>;
	   Burn: <<Burn kleding>>;
	  ],
     has pluralname concealed;     
        
Object kast "kledingkast" mijnslaap
 class Furniture,
  with name 'kast' 'kledingkast' 'eiken' 'zware',
       description "Met dit grote meubel ben je weken bezig geweest. Niet alleen heb je zelf de boom omgehakt waaruit hij gemaakt is, ook het zagen van de planken, het schuren, timmeren, lakken, en zelfs het subtiele houtsnijwerk heb je zelf gedaan. De herinnering aan die gelukzalige eerste maanden van jullie huwelijk, waarin Hilde en jij met beperkte middelen maar mateloos enthousiasme jullie kleine huisje inrichtten, doet je glimlachen.",
   has container ~open openable scenery male;
   
   Object kastkleding "grote hoeveelheid jurken, broeken en andere kledingsstukken" kast
    class Prop, 
     with name 'kleren' 'kledingsstuk' 'hoeveelheid' 'andere' 'grote' 'schoon' 'schone',
          description "In deze kast bewaren jullie al je kleren, netjes opgevouwen en gestreken, in keurige stapels gelegd. In een smal gedeelte aan de zijkant hangen de jurken van je vrouw.",
	  before [;
	    Take, Remove: "Dit is geen moment om kleding uit te gaan zoeken. Je werkkleding van de afgelopen dag voldoet prima voor je nachtelijke queeste.";
	  ],
	  parse_name [;
	    if (NextWord() == 'schoon' or 'schone' or 'nieuw' or 'nieuwe') {
	      if(NextWord() == 'hemd' or 'broek' or 'laarzen' or 'schoenen' or 'shirt' or 'spijkerbroek' or 'jeans' or 'kleding' or 'kleren') return 2;wn--;
	    };
	    if (NextWord() == 'in'){ if (NextWord() == 'kast' or 'kledingkast' or 'eiken' or 'zware') return 3;wn--;};wn--;wn--;
	    return -1;
	  ],
      has static transparent ~scenery male;
      
      Object jurken "jurken" kastkleding
       class Prop, 
	with name 'jurken' 'jurk',
	     description "Je laat je vingers langs de ruwe, stijve stof van de jurken glijden. Praktisch en zonder franje, de werkkleding van een bedrijvige huisvrouw. Helemaal achterin verstopt het witte satijn van Hildes trouwjurk zich alsof het met de rest van de kleding niet gezien wil worden.",
	 has concealed static pluralname;
	 
          Object trouwjurk "trouwjurk" kastkleding
	   class Prop,
            with name 'trouwjurk' 'satijn' 'bruidsjurk' 'bruiloftsjurk',
                 description  [;
		   print "Je pakt de koele, zachte stof vast en sluit voor een moment je ogen. Herinneringen aan je bruiloft komen met grote hevigheid boven; het is alsof er geen dag verstreken is, zo vers ligt het nog allemaal in je geest.";
		   if (verhaaltracker.bruiloft == 0) {Herinner(1);} ! Bruiloft
		   else{print "^";};
		   ],
		 before [;
		   Touch, Take: <<Examine self>>;
		 ],
             has concealed female static;
		 

      Object broeken "broeken" kastkleding
       class Prop, 
	with name 'broeken',
	     description "Deze stevige spijkerbroeken zijn de perfecte kleding voor een houthakker: niet kapot te krijgen.",
	 has concealed static pluralname;
	 
   Object houtsnijwerk "houtsnijwerk" mijnslaap
    class Prop, 
     with name 'houtsnijwerk' 'decoraties' 'snijwerk' 'figuren',
          description "Hartjes, vogeltjes, bloemen en andere figuren die jouw verliefde geest bevolkten toen je deze decoraties sneed kronkelen kunstig om elkaar heen.",
      has ;

      Object hartjes_snijwerk "gesneden hartjes" mijnslaap
       class Prop,
        with name 'hart' 'hartje' 'hartjes' 'harten',
	description "Kleine hartjes lopen langs de hele rand van de kledingkast.",
         has pluralname;

      Object vogels_snijwerk "gesneden vogels" mijnslaap
       class Prop,
        with name 'vogel' 'vogels' 'vogeltjes' 'vogeltje' 'vlucht' 'vluchten',
	description "In sierlijke patronen kronkelen in de kast uitgesneden vogeltjes zich om lange bloemenranken.",
         has pluralname;
      
      Object bloemen_snijwerk "gesneden bloemen" mijnslaap
       class Prop,
        with name 'bloemen' 'bloem' 'bloempje' 'bloempjes' 'rank' 'ranken',
	description "De grote kledingkast is versierd met bloemenranken waarin zowel inheemse als exotische en fantastische bloemen voorkomen. Vluchten kleine vogels wentelen zich er omheen.",
         has pluralname;      
	 
Object raam "raam" mijnslaap
  with name 'raam' 'venster' 'vensterglas' 'buiten',
       description "Onwerelds maanlicht valt door het raam naar binnen. Het dorp buiten is bedekt onder een dikke laag sneeuw, zodat de kerktoren als een beschuldigend priemende zwarte vinger uit een witte zee omhoog steekt. ~Hoe kan het toch,~ vraag je je af, ~dat dit landschap er zo liefelijk uit ziet, maar zo ijzig koud en vijandig is?~",
       before [;
         Search: <<Examine self>>;
	 Close: if(self has open){give self ~open; "Je sluit het raam, en de koude wind waait niet langer door de kamer.";};
	 Open: if(self hasnt open){give self open; "Het raam zwaait open, en een ijzige wind baant zich onmiddellijk een weg naar binnen. Beschenen door het licht van de maan laat je je blik over het winterlandschap glijden. Daar rechts, ver in het bos, ligt ergens het kasteel van de baron - het zwarte bouwwerk waarbinnen jouw kleine meid de grootste angsten doorstaat.";};
	 Climb: "Hoewel dat een manier is om buiten te komen en de tocht naar het kasteel te ondernemen, lijkt het je verstandiger om de trap te gebruiken.";
       ],
   has scenery openable ~open;
   
   Object barentopf_raam "Barentopf"
    class Prop,
     with name 'barentopf' 'topf',
          found_in mijnslaap tuin,
	  description [;
	    if (location == mijnslaap){
	      "Door het raam zie je de besneeuwde Barentopf achter het dorp omhoog komen. Het is de hoogste heuvel in de nabije omgeving.";
	    }
	    else{
	      "Je ziet de besneeuwde Barentopf achter het dorp oprijzen. Het is de hoogste heuvel in de nabije omgeving, maar hij ligt niet in de goede richting wanneer je de baron wil bereiken.";
	    };  
	   ],
      has scenery male;
      
   Object dorp_raam "dorp"
    class Prop,
     with name 'dorp' 'huizen' 'woningen' 'stad' 'stadje',
          found_in mijnslaap tuin,
	  description [;
	    if (location == mijnslaap){
	      "Omdat je huis op een heuvel aan de rand van het dorp ligt, heb je vanuit het raam een mooi uitzicht over de andere woningen. Slechts achter enkele ramen branden nog lichtjes; verder is het dorp in deze winternacht gehuld in duisternis en sneeuw.";
	    }
	    else{
	      "Jouw huis staat aan de rand van het dorp, dat in deze koude decembernacht gebukt gaat onder een dikke laag sneeuw. Op dit tijdstip van de nacht is er niemand meer op straat. Het dorp hult zich in stilzwijgen.";
	    };  
	   ],
      has scenery;

   Object sneeuw_raam "sneeuw"
    class Prop,
     with name 'sneeuw' 'wit' 'witte' 'laag',
          found_in mijnslaap tuin,
	  description "Een dik pak witte sneeuw heeft zich de afgelopen dagen op het landschap genesteld. In de straten is het gedegenereerd tot vieze bruine smurrie, maar verder geeft de sneeuw de wereld een majestueuze uitstraling.",
      has scenery male;
      
   Object kerk_raam "kerk"
    class Prop,
     with name 'kerk' 'kerktoren' 'toren',
          found_in mijnslaap tuin,
	  description [;
	    if (location == mijnslaap){
	      "De kerktoren steekt als een beschuldigend priemende zwarte vinger uit de witte sneeuw omhoog.";
	    }
	    else{
	      "Het puntje van de kerktoren steekt net boven de huizen aan de overkant van de straat uit, als een zwarte vinger tegen de met sterren bezaaide hemel.";
	    };  
	   ],
      has scenery male;
      
   Object sterren_raam "sterren"
    class Prop,
     with name 'sterren' 'ster' 'melkweg' 'hemel' 'sterrenhemel' 'fonkelende',
          found_in mijnslaap tuin haarslaap bos_1 bos_2 bos_3 ophaalbrug,
	  description [;
	     if (wolvin.status == 99) {
	      "De nachtelijke hemel is bezaaid met duizenden fonkelende sterren, als evenzovele ogen die de dieren in de gaten houden.";
	     } else
	      "De nachtelijke hemel is bezaaid met duizenden fonkelende sterren, als evenzovele ogen die de mensheid in de gaten houden.";
	   ],
      has scenery male pluralname;   
      
   Object maan_raam "maan"
    class Prop,
     with pname '.p' 'maan' '.p' 'maanlicht' '.p' 'schijnsel' '.p' 'mannetje' '.p' 'mannetje' 'in' 'de' 'maan',
          found_in mijnslaap tuin bos_1 bos_2 bos_3 ophaalbrug overloop,
	  description [;
	    if (location == mijnslaap){
	      "Door het raam kan je de volle maan tegen de sterrenhemel zien staan. Even lijkt het alsof het mannetje in de maan bemoedigend naar je knipoogt, maar dan neemt hij weer zijn gewone mysterieuze pose aan.";
	    };
	    if(location == overloop){
	      if(over_deur has open)
	        {"Het zilveren licht van de maan schijnt vanuit de slaapkamer naar binnen.";}
	      else
	        {"De deur naar je slaapkamer is gesloten, dus je kan de maan niet zien.";};
	    }
	    else if (wolvin.status ~= 99){
	      "Het mannetje in de maan kijkt je kil, haast beschuldigend, aan vanuit zijn verheven positie.";
	    } else {
	      "De witte bol geeft genoeg licht voor jouw scherpe ogen om bij te zien.";
	    };  
	  ],
      has scenery male;      
         
   Object bos_raam "bos"
    class Prop,
     with name 'bos' 'woud',
          found_in mijnslaap tuin,
	  description "Het woud ligt als een inktzwarte massa over de heuvels. Op dit uur en in dit jaargetijde is het een gevaarlijke plaats, vol wilde dieren.",
      has scenery;
      
Object over_deur
 class Deur, 
  with name '.p' 'deur' '.p' 'deur' 'naar' '.x' 'de' '.or' 'mijn' '.or' 'onze' 'slaapkamer' '.or' 'overloop',
       short_name [;
          if (location == mijnslaap) print "deur naar de overloop";
	  else print "deur naar de slaapkamer";
	  return true;
         ],
       description [;
          if (location == mijnslaap) "De nauwsluitende deur scheidt je slaapkamer van de overloop en daarmee de rest van het huis.";
	  else "Deze deur leidt terug naar de slaapkamer.";
	  
	 ],
       found_in mijnslaap overloop,
       door_dir [;
         if (location == mijnslaap) {return n_to;}
	 else {return s_to;};
	 ],
       door_to [;
         if (location == mijnslaap) return overloop;
	 else return mijnslaap;
         ],
   has door openable ~open scenery male;
   
   
Object nachtkastje "vuren nachtkastje" mijnslaap
 class PropSup,
  with name 'kastje' 'nachtkastje' 'vuren',
       description [;
         print "Een simpel nachtkastje van vurenhout, het allereerste meubel dat je ooit zelf getimmerd hebt.";
         if(parent(foto) == self){print " Op het nachtkastje staat een familiefoto.";};
         "";    
       ],
       before[;
         Open: "Achter het deurtje van het nachtkastje ligt niets dat je bij het bevrijden van je dochter zou kunnen helpen.";
       ],
   has ;
   
   Object deurtje "deurtje" nachtkastje
    class Prop,
     with name 'deurtje',
          description "Een simpel vuren deurtje zonder slot.",
      has ;

Object foto "familiefoto" nachtkastje
  with name 'foto' 'familiefoto' 'prent' 'plaatje' 'portret',
       description [;
         if (verhaaltracker.status < 6){"Deze foto, gemaakt ter ere van het tienjarig huwelijk van jou en Hilde, is alweer enkele jaren oud. Plechtig staan jullie als twee zwart-witte standbeelden naast elkaar, voor de gelegenheid weer in jullie trouwkostuums gehesen. Op de voorgrond, dicht tegen jou aan, staat jullie dochter Maartje. Kleine Maartje, in haar prachtige witte jurkje, een stralende lach op haar gezicht. Op de foto heb je beschermend een arm over haar schouder geslagen. Maar nu is zij ontvoerd door de kwaadaardige baron... nogmaals zweer je dat je alles in je macht zal doen om haar te bevrijden.";}
	 else {"Deze foto, gemaakt ter ere van het tienjarig huwelijk van jou en Hilde, is alweer enkele jaren oud. Plechtig staan jullie als twee zwart-witte standbeelden naast elkaar, voor de gelegenheid weer in jullie trouwkostuums gehesen. Op de voorgrond, dicht tegen jou aan, staat jullie dochter Maartje. Kleine Maartje, in haar witte jurkje, trekt een ernstig gezicht. Ze lijkt erg ongemakkelijk met de arm die je op haar schouder hebt gelegd.";};
       ],
       after [;
         PutOn: if(parent(self) == nachtkastje){give self concealed;};
	 Take: give self ~concealed; return false;
	 default: return false;
       ],
       before [;
	     Burn:
	      if(TestScope(toorts,player)) {
	       if(second == toorts || second == nothing) {
	         if(toorts has general) {
		   remove self;
		   "De foto die jouw gelukkige familieleven placht te documenteren wordt door het vuur volledig verteerd, tot niet meer dan de schaduw van een leugen overblijft.";
		 } else {
		   "Nu de toorts gedoofd is kan je er niets meer mee aansteken.";
		 }
	       } else {
	         "Daarmee kan je niets aansteken.";
	       } 
	     }        
       ],
   has male concealed;

   
   
   
   
Object overloop "Op de overloop"
  with name 'overloop' 'gang' 'boven' 'duister',
       description [;
         print "De overloop is gehuld in een schemerig duister. ";
	 if(over_deur has open){print "Maanlicht schijnt naar binnen door de open deur naar de slaapkamer in het zuiden. ";} else {print "De deur naar je slaapkamer is gesloten. ";};
	 if(maartje_deur has open){print "Aan de noordkant van de overloop staat de rode deur naar Maartjes kamer op een kier. ";} else {print "Aan de noordkant van de overloop leidt een rood geschilderde deur naar de kamer van je dochter Maartje. ";};
	 "Naast de trap naar beneden staat een elegant kastje, waarboven een grote spiegel in een vergulde lijst prijkt.";
	 ],
       s_to over_deur,
       n_to maartje_deur,
       d_to over_trap,
       out_to over_trap,
       before [;
        Go: if(noun == d_to) {TrapNaarTuin(); return true;};
       ],
   has light transparent; 
   
Object kastje "kastje" overloop
  with name 'kastje' 'kast' 'dressoir',
       description "Dit sierlijk gesneden kastje is een van de weinige meubels in huis die je niet zelf gemaakt hebt: het komt uit de erfenis van Hildes grootmoeder. De twee deurtjes aan de voorkant sluiten niet helemaal goed, een mankement dat je al jaren van plan bent te verhelpen, waar het echter nooit van komt.",
   has container openable ~open scenery;
   
   Object deurtjes "deurtjes" overloop
     with name 'deurtjes' 'deurtje' 'deuren' 'kastdeur' 'kastdeurtje' 'kastdeuren' 'kastdeurtjes',
          description "Gemaakt van hetzelfde kersenhout als de rest van het kastje zijn ze door de tand des tijds enigszins scheef in hun scharnieren komen te hangen.",
	  before [;
	    Open: <<Open kastje>>;
	  ],
      has scenery pluralname;
      
      Object scharnieren "scharnieren" overloop
        with name 'scharnier' 'scharnieren' 'koperen',
	     description "Vier koperen scharnieren die nog prima functioneren, maar door ouderdom los zijn komen te zitten.",
	 has scenery pluralname;
     
   
Object fotoboek "fotoboek" kastje
  with pname 
          '.p' 'boek' '.p' 'fotoboek' '.p' 'fotos' '.p' 'foto^s' '.p' 'album' '.p' 'fotoalbum' '.p' 'foto' '.p' 'volgende' 'pagina' '.or' 'bladzijde' '.or' 'foto' '.p' 'meer' 'fotos' '.or' 'foto^s',
       gesloten 1,
       description [;
         self.gesloten = 0;
         if (verhaaltracker.fotoalbum < 5) {Herinner(2);} ! Fotoalbum
	 else{"Je bladert nogmaals door het fotoalbum, maar laat je ditmaal niet meeslepen door je herinneringen. Hoe goed je ook kijkt, de tweede helft van het boek blijft leeg.";};
        ],
       before [;
         Consult, Open: <<Examine self>>;
	 Close: if (self.gesloten == 1) {
	     "Het fotoalbum is al gesloten.";
	   } 
	   else {
             self.gesloten = 1;
	     if (verhaaltracker.fotoalbum == 5) {
	       "Met een meewarige zucht sluit je het fotoalbum.";
	     } 
	     else {
	       "Je besluit de rest van de foto's niet te bekijken, en sluit het fotoalbum.";
	     };
	   };
	 Burn:
	     if(TestScope(toorts,player)) {
	       if(second == toorts || second == nothing) {
	         if(toorts has general) {
		   remove self;
		   "Je geeft het boek prijs aan de vlammen en ziet, met een mengeling van afschuw en grimmige tevredenheid, hoe zelfs de herinnering aan een verloren geluk ten prooi valt aan hun eeuwige honger.";
		 } else {
		   "Nu de toorts gedoofd is kan je er niets meer mee aansteken.";
		 }
	       } else {
	         "Daarmee kan je niets aansteken.";
	       }
	     }
       ],
   has transparent;
   
   Object lijmresten "lijmresten" fotoboek
    class Prop,
     with name 'lijm' 'lijmresten',
          description "Simpele lijmresten, alsof alle foto's vanaf een bepaalde datum uit het album zijn getrokken."
      has pluralname concealed;

Object spiegel "spiegel" overloop
 class Prop,
  with name 'spiegel',
       description [;
         print "Uit de spiegel staar je jezelf tegemoet";
	   if(kleding has worn) {
             print ", een heldhaftige blik in je ogen. Je stoere houthakkerskleding zit als gegoten en laat de stevige spierbundels in je armen goed uitkomen. ";
           }
           else {
             print ". In je nachthemd zie je er meer wanhopig dan heldhaftig uit, maar schijn bedriegt. ";
           };
         print "Een grimmige glimlach speelt om je mondhoeken als je denkt aan de angst die de baron zal voelen wanneer jij zijn kasteel binnen dringt om hem ";
	   if(parent(axe) == player){
	     "met je zware bijl te onthoofden.";
	   }
	   else {
	     "met je stevige vuisten tot moes te slaan.";
	   };
       ],
       before [;
         Attack: "Daar is het nog niet de tijd voor.";
       ],
   has male;
   
   Object spiegel_lijst "lijst" overloop
    class Prop,
     with name 'lijst' 'vergulde',
          description "De overdadig versierde, met goudverf beschilderde lijst zou beter in het interieur van je schoonmoeder passen dan in dat van jullie - niet verwonderlijk, aangezien zij hem aan jullie gegeven heeft. Zolang ze nog regelmatig bij jullie op bezoek komt kan je hem echter niet weggooien.",
	  before [;
	   Attack: "Hoe graag je het ook zou willen, sociale conventies houden je tegen.";
	  ],
      has male;
   
Object maartje_deur
 class Deur, 
  with pname 'deur' 'rode' 'rood' '.p' '.x' 'rode' 'deur' 'naar' '.x' 'Maartjes' '.or' 'Maartjes' 'kamer' '.or' 'overloop',
       short_name [;
          if (location == haarslaap) print "deur naar de overloop";
	  else print "deur naar Maartjes kamer";
	  return true;
         ],
       description [;
          if (location == overloop) "Deze vrolijk rood geschilderde deur leidt naar de kamer van je ontvoerde dochter Maartje.";
	  else "Deze deur leidt terug naar de overloop.";
	  
	 ],
       found_in haarslaap overloop,
       door_dir [;
         if (location == haarslaap) {return s_to;}
	 else {return n_to;};
	 ],
       door_to [;
         if (location == haarslaap) return overloop;
	 else return haarslaap;
         ],
   has door openable ~open scenery male;
   
Object over_trap "trap"
  with pname 'trap' '.p' 'beneden' '.p' '.x' 'houten' 'trap' '.x' 'naar' '.x' 'beneden' '.p' '.x' 'naar' 'beneden' '.p' '.x' 'naar' 'buiten',
       description "De houten trap wentelt zich een inktzwarte diepte in.",
       found_in overloop,
       door_dir d_to,
       door_to tuin,
       before [;
         Climb, Go, Enter: 
	   if (noun == self || noun == d_obj || noun == tuin) {
	     TrapNaarTuin();
	     return true;
	   };
       ],
   has door scenery male open;
   
   
   [ TrapNaarTuin ;
     print "Behoedzaam zoek je je weg door de duisternis naar beneden. In de gang neem je even de tijd om je lange winterjas aan te trekken, en dan open je de voordeur en stap je naar buiten de tuin in.";
     VraagToets(0,0,0);
     PlayerTo(tuin);
     move jas to player; give jas worn; give tuindeur open;
     return true;
   ];
   
   [ TuinNaarTrap ;
     if (tuindeur has open) {print "Door de open voordeur stap je weer naar binnen.";}
       else {print "De voordeur openend stap je je huis binnen.";};
     print " Je hangt je winterjas terug op de kapstok, en klimt in het donker de trap op naar de overloop.";
     VraagToets(0,0,0);
     PlayerTo(overloop);
     move jas to over_trap; give jas ~worn;
     return true;   
   ];

   Object jas "winterjas" over_trap
     with name 'jas' 'winterjas',
          description [;
	    print "Recentelijk heb je deze warme winterjas gekocht, na lang aandringen van je vrouw. Zeker, er zaten gaten in je oude, en hij was niet half zo warm, maar hij was vertrouwd, het was "; style bold; print "jouw"; style roman; " winterjas - maar vrouwen begrijpen dat soort dingen niet.";
	  ],
	  before [;
	     Disrobe: if(verhaaltracker.status < 6 && kleding hasnt worn) {
	         "Het is buiten ijskoud. Alleen je dikke winterjas beschermt je tegen onderkoeling.";
	       }
	       else if (verhaaltracker.status < 6 && kleding has worn) 
	         "Het is buiten ijskoud. De dikke winterjas en je werkkleding zijn hard nodig om je te beschermen tegen onderkoeling.";
             Burn: <<Burn kleding>>;
	  ],
      has clothing male;
   
      
   
Object haarslaap "In Maartjes kamer"   
  with name 'maartje' 'kamer' 'slaapkamer' 'maartje^s',
       description "Zonder Maartjes stralende aanwezigheid lijkt haar kamer doods en leeg. Het geeft een droeve aanblik: een bed waar niet in geslapen wordt, een poppenhuis waar niet mee gespeeld wordt, een bureau waaraan niet gestudeerd wordt. De bonte kleuren waarin jij haar plafond en meubilair geverfd hebt verschijnen in het bleke licht van de sterren als een waaier aan grijstinten. De deur in het zuiden leidt terug naar de overloop.",
       s_to maartje_deur,
       react_before [;
         Sleep: 
	    "Gewoon weer in slaap vallen en dromen van Maartje, niets doen, nergens aan hoeven te denken dan haar ranke verschijning - maar zo gemakkelijk is het niet. Ze is ontvoerd door de baron, en die wetenschap zal je dromen verstoren. Je zal niet kunnen slapen tot je tot actie bent overgegaan. En zelfs als het je zou lukken om in slaap te vallen, dan is er morgen weer een dag, en overmorgen - en het zal niet altijd blijven lukken. Beter om het kwaad vandaag onder ogen te zien, dan om de confrontatie uit te stellen tot morgen.";
       ],
   has light transparent; 
   
Object maartjebed "Maartjes bed" haarslaap
 class Furniture, 
  with name 'bed' 'Maartjes' 'Maartje^s' 'ledikant' 'kinderbed' 'kinderledikant',
       geslapen 0,
       description [;
         print "Onder het raam staat Maartjes bed, een ruim kinderledikant dat, zoals bijna alle meubels in jullie huis, een product is van jouw nijvere arbeid.";
         if(self.geslapen == 0){
	   if(parent(kussen) == self){
	     print " Het bed is keurig opgemaakt, de dekens perfect recht, het kussen opgeklopt. Te maagdelijk, te onaangeraakt, alsof het niet bestemd is voor menselijk gebruik.";
	   }
	   else{
	     print " Het bed is keurig opgemaakt, de dekens perfect recht, al mist het kussen. Er is duidelijk niet in geslapen.";
	   };
	 } 
	 else{
	   if(parent(kussen) == self){
	     print " De dekens op het bed liggen er slordig bij en het kussen ligt scheef, alsof er recent iemand in het bed heeft geslapen. De kamer ziet er hierdoor minder doods uit.";
	   }
	   else{
	     print " De dekens op het bed liggen er slordig bij, alsof er recent iemand in het bed heeft geslapen. De kamer ziet er hierdoor minder doods uit.";
	   };
	 };       
	 "";
       ],
       before [;
         Search, Look: if(parent(dagboek_sleutel) == kussen) {
	        move dagboek_sleutel to player;
		give dagboek_sleutel ~concealed;
		"Verstopt onder het kussen vind je een klein koperen sleuteltje, dat je verwonderd oppakt.";
	      } else return false;
	 Enter: self.geslapen = 1; return false;

       ],
   has enterable container transparent scenery open proper;
   
   Object deken_maartje "Maartjes deken" maartjebed
    class Prop,
     with name 'deken' 'dekens' 'dekbed' 'laken' 'lakens',
          description [;
	    if(maartjebed.geslapen == 0){
	      "De rode en blauwe dekens liggen en strak en netjes bij.";
	    }
	    else {
	      "De rode en blauwe dekens zijn slordig over het bed gedrapeerd.";
	    };
	  ],
	  before [;
	    Attack: maartjebed.geslapen = 1;
	            "Je slaat een aantal maal verwoed op de dekens van Maartjes bed om hun onverdraaglijke netheid te verstoren.";
            LookUnder: maartjebed.geslapen = 1;
	            "Je kijkt onder de dekens, maar vindt niets.";
            Pull: maartjebed.geslapen = 1;
	            "Je trekt verwoed aan de dekens van Maartjes bed om hun onverdraaglijke netheid te verstoren.";
	    Push, Take, Kreuk: maartjebed.geslapen = 1;
	            "Je verfrommelt de dekens van Maartjes bed en werpt ze weer op het bed om hun onverdraaglijke netheid te verstoren.";
	  ],
      has proper;
   
   Object kussen "Maartjes kussen" maartjebed
     with name 'kussen' 'Maartjes' 'Maartje^s' 'sloop' 'kussensloop',
          description "Maartjes kussen is heerlijk zacht, want gevuld met veren. Er zit een vrolijk kussensloop in alle kleuren van de regenboog omheen.",
	  before [;
	    Examine, Search, LookUnder: if(parent(dagboek_sleutel) == kussen) {
	        move dagboek_sleutel to player;
		give dagboek_sleutel ~concealed;
		"Verstopt onder het kussen vind je een klein koperen sleuteltje, dat je verwonderd oppakt.";
	      } else return false;
	    Take: if(parent(dagboek_sleutel) == kussen) {
	        move dagboek_sleutel to player;
		give dagboek_sleutel ~concealed;
		"Verstopt onder het kussen vind je een klein koperen sleuteltje, dat je verwonderd oppakt.";
	      } else {
	        "Het kussen is groot en onhandig om mee te nemen op je queeste. Op het bed is het beter op zijn plaats.";
	      };
	  ],
      has proper;

      Object dagboek_sleutel "sierlijk sleuteltje" kussen
        with name 'sleutel' 'sleuteltje' 'koperen' 'klein' 'sierlijk' 'dagboeksleutel',
	     description "Het met delicate patronen versierde koperen sleuteltje vertoont sporen van intensief gebruik.",
	     before [;
	       Drop, ThrowAt:
	         if(parent(player) == kasteel_kerker_cel && parent(self) == player) {
		   if(kasteel_kerker_cel has locked)
		     sleutelweg.select(1);
		     return true;
		 }
	       return false;
	     ],
	 has concealed;
   
Object raam_maar "raam" haarslaap
  with name 'raam' 'venster' 'vensterglas' 'buiten',
       description "Dreigend kijken de naaldbossen je aan door het venster, hun vijandig stilzwijgen een belofte van ontbering en gevaar. Ergens, diep in hen verscholen, ligt het slot van de baron. En ergens, diep in zijn slot, de kerker waar Maartje gevangen zit. Je ziet haar voor je, hoe ze nu, op dit moment, schreit om haar vader, eenzaam, alleen, verlaten, opgesloten in een steenkoude cel.",
       before [;
         Search: <<Examine self>>;
	 Close: if(self has open){give self ~open; "Je sluit het raam, en een doodse stilte keert terug.";};
	 Open: if(self hasnt open){give self open; "Het raam zwaait open, en het geluid van de wind door het dennenbos sluipt zachtjes naar binnen. Ergens, ver weg, hoor je het huilen van wolven.";};
	 Climb: "Hoewel dat een manier is om buiten te komen en de tocht naar het kasteel te ondernemen, lijkt het je verstandiger om de trap te nemen.";
       ],
   has scenery openable ~open;   
   
   Object sneeuw_maar "sneeuw" haarslaap
    class Prop,
     with name 'sneeuw' 'wit' 'witte' 'laag',
          description "Een dik pak sneeuw heeft zich de afgelopen dagen op het landschap genesteld. De boomtakken buigen zwaar door onder hun witte last.",
      has scenery male;
      
   Object maan_maar "maan" haarslaap
    class Prop,
     with name 'maan',
          description "Vanaf deze kant van het huis is de maan niet te zien.",
      has scenery male;      
         
   Object bos_maar "bos" haarslaap
    class Prop,
     with name 'bos' 'woud' 'bossen' 'bomen' 'boom' 'dennenbos' 'naaldbos' 'dennenbossen' 'naaldbossen',
	  description "Het woud ligt als een inktzwarte massa over de heuvels. En in het hart van deze duisternis leeft de kwade baron.",
      has scenery;
   
   Object heuvels_raam "heuvels"
    class Prop,
     with name 'heuvels' 'heuvel',
          found_in haarslaap mijnslaap,
	  description "Lichte glooi@:ingen in het landschap geven deze streek 's zomers een pittoresk uiterlijk. In deze koude wintermaanden lukt het ze echter niet de sombere wouden op te vrolijken.",
      has pluralname scenery;      
      
   Object wolven_maar "wolven" haarslaap
    class Prop,
     with name 'wolven' 'wolf',
          counter 0,
	  description [;
	    print "Je neemt geen beweging waar in het bos, niet van deze afstand.";
	    if (raam_maar has open) {
	      print " Maar een weeklagend gehuil stijgt, nauwelijks hoorbaar, op vanaf verre heuvels.";
	    };
	    "";
	  ],
	  before [;
	    Listen: if(self.counter == 0){self.counter = 1; "Je buigt uit het raam om het gehuil van een roede wolven beter te kunnen horen. Even lijkt het alsof de verschillende jammerklachten een melodie vormen, maar dan verstommen ze plotseling. Een onheilszwangere stilte volgt, en je haalt opgelucht adem wanneer een kleine minuut later ergens anders in het bos het geluid van een eenzame wolf weerklinkt.";}
	    else {
	      "Vanuit de diepte van het woud stijgt zo nu en dan het gehuil van wolven op.";
	    };
	  ],
      has scenery pluralname;
      
    Object wind "wind" haarslaap
     class Prop,
      with name 'wind',
           before [;
	     Examine, Listen: "De wind suist zachtjes over de sneeuw-beladen takken van het dennenbos.";
	   ],
       has male;
      
Object poppenhuis "poppenhuis" haarslaap
 class Furniture,
  with name 'poppenhuis',
       description "Ooit heb je dit poppenhuis zelf in elkaar gezet: drie verdiepingen, met deurtjes en raampjes die open en dicht kunnen, allerhande meubels, en houten popjes met fijn gesneden gezichten die de woning kunnen bevolken. Hilde heeft gordijntjes gemaakt, vloerkleedjes en kleertjes voor de poppen.",
       played 0,
       before [;
         Play: if(self.played == 0) {
	           self.played = 1;
	           "Je zet je op je knie@:en voor het poppenhuis neer, en kijkt de popjes even mismoedig aan. Dan pak je de moederpop met je linkerhand op en de vaderpop met je rechterhand. Je laat vader door een deurtje het huis binnenkomen.^^~Zo moeder,~ zegt hij, ~ik heb vandaag weer hard gewerkt. Je hebt geen idee hoe hongerig ik ben.~^^~Nou vader,~ antwoordt ze in een raar hoog stemmetje, ~dat schikt, want ik heb een hele poppenpot vol poppenpap gekookt vandaag. Kinders, komen jullie eten, vader is thuis!~^^Je zet de twee popjes op hun poppenstoeltjes neer, en pakt de poppendochter. Ze loopt naar de huiskamer, en wanneer ze haar vader ziet roept ze: ~Pappie!~^^^Verdrietig sluit je je ogen en leg je de popjes weg.";}
	        else {
		   "Je kan beter Maartje gaan bevrijden dan nog langer met het poppenhuis spelen.";
		  };
	       
       ],
   has scenery container open;
   
   Object pop_deurtjes "poppendeurtjes" poppenhuis
    class Prop,
     with name 'deurtjes' 'deurtje' 'klinken' 'deurklinken' 'deurklinkjes' 'deurklink' 'klink' 'poppendeurtjes' 'poppendeurklinkjes',
          description "Geschilderde poppendeurtjes met bewegende poppendeurklinkjes scheiden de verschillende kamers in het poppenhuis. Zo hebben de poppen wat privacy, en minder last van tocht.",
      has pluralname;
      
   Object pop_meubels "poppenmeubels" poppenhuis
    class Prop,
     with name 'meubels' 'stoeltjes' 'tafeltjes' 'stoeltje' 'tafeltje' 'poppenmeubels' 'poppenstoeltjes',
          description "Kleine poppenstoeltjes staan gegroepeerd rond poppentafeltjes.",
      has pluralname;
   
   Object pop_raampjes "poppenraampjes" poppenhuis
    class Prop,
     with name 'raampjes' 'raampje' 'poppenraampjes' 'poppenramen',
          description "De zijkanten van het poppenhuis worden gesierd door poppenraampjes, waar verschuifbare poppengordijntjes voor hangen. Hier kunnen de poppen door naar buiten kijken, want laten we wel wezen: de voorkant van het huis is voor ons dan wel open, maar voor de poppen zelf natuurlijk niet.",
      has pluralname;

   Object pop_gordijntjes "poppengordijntjes" poppenhuis
    class Prop,
     with name 'gordijntjes' 'gordijntje' 'poppengordijntjes' 'poppengordijntje',
          description "Van kleine lapjes stof heeft Hilde gordijntjes gemaakt die passen bij het interieur van de poppenwoning. Ook poppen hebben stijl.",
	  before [;
	    Pull, Push: "Je schuift de delicate poppengordijntjes dicht en weer open.";
	  ],
      has pluralname;

   Object pop_kleedjes "poppenkleedjes" poppenhuis
    class Prop,
     with name 'kleedjes' 'kleedje' 'poppenkleedjes' 'poppenkleedje' 'vloerkleedjes' 'vloerkleedje' 'poppenvloerkleedjes' 'poppenvloerkleedje',
          description "Zachte poppenkleedjes met wilde patronen bedekken de houten vloer van het poppenhuis, en geven de poppenkamers die knusse uitstraling die ze anders zouden missen.",
      has pluralname;
      
   Object pop_kleertjes "poppenkleertjes" poppenhuis
    class Prop,
     with name 'kleertjes' 'kleertje' 'poppenkleertjes' 'poppenkleertje' 'poppenkleding',
          description "De poppenkleertjes zijn met oog voor het kleinste detail door Hilde genaaid: jurkjes, broekjes, shirtjes, rokjes, schoentjes, zelfs sokjes en hoedjes zijn niet vergeten. Misschien heb je Hilde wel nooit zo gelukkig gezien als toen ze hier al haar creativiteit en liefde in kon leggen.",
      has pluralname;   
   
   Object poppen "poppen" poppenhuis
     with 
          name 'poppen' 'pop' 'vaderpop' 'moederpop' 'poppenzoon' 'poppenzoontje' 'poppendochter' 'poppendochtertje' 'popjes',
          description [;
	      if(poppenhuis.played == 0) "In het poppenhuis leven vier popjes: een vaderpop, een moederpop, een poppenzoon en een poppendochter. Vaderpop zit een krant te lezen op de bank in de woonkamer, terwijl moederpop, waarschijnlijk bezig met een maaltijd, in de keuken staat. Het poppenzoontje staart bedachtzaam uit een raam naar buiten, en de poppendochter ligt, nog gekleed in haar rode jurkje, op bed in haar slaapkamer.";
	      if(poppenhuis.played ~= 0) "In het poppenhuis leven vier popjes: een vaderpop, een moederpop, een poppenzoon en een poppendochter. Vaderpop en moederpop zitten op de stoeltjes rond het tafeltje, waar je ze zojuist zelf hebt neergezet. Het poppenzoontje staart bedachtzaam uit een raam naar buiten, en de poppendochter ligt, nog gekleed in haar rode jurkje, in de keuken op de grond.";
	   ],
	  before [;
	    Take: "De poppen zijn de enigen in jullie huis die op dit moment een normaal gezinsleven hebben, en je bent niet van plan dat te gaan verstoren.";
	    Play: <<play poppenhuis>>;
	  ],
      has pluralname;
     
Object bureau "bureau" haarslaap
 class Furniture,
  with name 'bureau' 'tafel' 'schrijftafel' 'werktafel' 'beukenhout' 'schriften' 'potloden',
       description "Het kleine bureau van gelakt beukenhout is bezaaid met vellen papier, schriften en kleurpotloden.",
   has scenery supporter;
   
   Object papier "vellen papier" bureau
    class Prop,
     with name 'vellen' 'papier' '.p' 'papier' '.p' 'vel' '.p' 'papieren' '.p' 'stapels' '.x' 'papier' '.or' 'papieren' '.p' 'wit' 'onbeschreven',
          description "Een aantal nette stapels onbeschreven papier zijn links op het bureau gelegd, maar tientallen betekende vellen liggen chaotisch verspreid over het tafelblad.",
      has pluralname;
      
      Object tekeningen "tekeningen" bureau
       class Prop,
        with pname 'tekening' '.p' 'tekeningen' '.p' 'betekende' '.or' 'beschreven' '.or' 'betekend' 'vel' '.or' 'vellen' '.or' 'papier' '.or' 'papieren',
	     description "Het zijn allemaal vrolijke tekeningen die Maartje gemaakt heeft: vlinders die vliegen door een weiland vol bloemen; een huisje met jullie gezin ervoor; een vader en dochter die sleetje rijden. De felle kleuren spatten van het blanke papier, zelfs in het zwakke licht van de sterren.",
	 has pluralname;
	     
	
   
   Object dagboek "dagboek" bureau
     with counter 0,
          pname '.x' 'rode' '.x' 'rode' 'dagboek' '.or' 'nep-leer',
	  with_key dagboek_sleutel,
	  before [;
	    Open: if (self has locked && parent(dagboek_sleutel) == player) {
	        <Unlock self dagboek_sleutel>;  return true;
	     }
	     else {
	       <<Examine self>>;
	     };
            Unlock: if (self hasnt locked) "Het dagboek is al van het slot gehaald.";
	      if (self has locked && second == dagboek_sleutel) {
	         print "Je steekt het koperen sleuteltje in het slot van het dagboek, en draait het voorzichtig rond. Met een zachte klik springt het slot open.^";
		 give self ~locked;
		 return true;}
	      print "Na enkele mislukte pogingen concludeer je dat ", (the) second, " niet de sleutel tot dit dagboek "; IsofZijn(second); print ".^"; return true;
	    Consult, Examine: if (self has locked && parent(dagboek_sleutel) ~= player) {
	      "Het in rood nep-leer gebonden boekje moet wel een dagboek zijn, aangezien het dicht zit met een klein koperen slot. Maar hoewel je brandt van nieuwsgierigheid, ben je niet van plan Maartjes dagboek te beschadigen.";
	    }
	    else {
	      if (self has locked && parent(dagboek_sleutel) == player) {<Unlock self dagboek_sleutel>; print "^";}
	      if (self.counter == 0) {
	        self.counter = 1;
		print "Je voelt je absurd schuldig wanneer je het dagboek opent om te lezen wat je dochtertje er voor geheimen aan heeft toevertrouwd. Natuurlijk hoort een vader dit niet te doen, maar dit is een noodgeval, en nood breekt wet. Misschien staat er wel iets in dat je kan helpen haar te bevrijden.";
		
		VraagToets(0,0,0);
		
		"Maar er staat niets geschreven in het dagboek, geen woord. In plaats daarvan zijn alle bladzijden in de eerste helft van het dagboek helemaal ingekleurd met zwarte inkt. Van boven tot onder, van links tot rechts, met een nooit falende precisie is op elke pagina het witte papier veranderd in een egaal zwart vlak. De tweede helft van het dagboek is nog blank, onaangeraakt, smetteloos. Verwilderd sluit je het dagboek.";
	      }
	      else {
	        "Nogmaals bekijk je het dagboek, en opnieuw zijn er alleen egaal zwart ingekleurde pagina's in de eerste, en lelieblanke in de tweede helft. Maartje heeft nooit een woord geschreven, of ze allemaal onzichtbaar gemaakt.";
	      };
	    };
	   Burn:
	     if(TestScope(toorts,player)) {  
	       if(second == toorts || second == nothing) {
	         if(toorts has general) {
		   remove self;
		   move kaft to location;
		   "Het dagboek vat onmiddellijk vlam, en het diepe zwart van inkt verandert in het grauwe zwart van as. Na enkele minuten is alleen nog de onbrandbare nep-lederen kaft van het dagboek over, een vorm zonder inhoud.";
		 } else {
		   "Nu de toorts gedoofd is kan je er niets meer mee aansteken.";
		 }
	       } else {
	         "Daarmee kan je niets aansteken.";
	       }
	     }
	  ], 
      has openable ~open lockable locked;
      
Object plafond "plafond" haarslaap
 class Prop,
  with name 'plafond' 'boven',
       description "Beschilderd met liefelijke taferelen straalt het plafond van Maartjes kamer onder normale omstandigheden vrolijkheid en zorgeloosheid  uit.",
   has ;
       
Object meubilair "meubilair" haarslaap
 class Prop,
  with name 'meubilair' 'meubels',
       description "Een bed, een bureau en een prachtig in elkaar gezet poppenhuis, compleet met kleine bedjes, bureautjes en -  nee, niet met een klein poppenhuisje - vormen het meubilair van Maartjes kamer.",
   has ;
   
Object beer "knuffelbeer" haarslaap
  with name 'beer' 'knuffel' 'knuffelbeer' 'Bruin' 'teddybeer',
       description [;
       if(verhaaltracker.status < 5){
         "Bruin is al vele jaren Maartjes favoriete knuffel en trouwste kompaan. De glimlach op zijn snuit is bemoedigend, en ook al zijn Bruins ogen slechts knopen, toch lijkt er iets van intelligentie in zijn blik te zitten.";
        }	 
	else {
	  "Bruin was altijd jaren Maartjes favoriete knuffel en trouwste kompaan. Maar de glimlach op zijn snuit is eerder weemoedig dan bemoedigend, en ook al zijn Bruins ogen slechts knopen, toch lijken ze elk moment bitter te kunnen gaan wenen.";
	};
       ],
       before [;
           Knuffel: "Je pakt de beer stevig in je armen, en knuffelt hem alsof je leven er van af hangt. Een traan rolt over je wangen als je bedenkt dat Maartje niet eens de troost van haar knuffel heeft.";
	   
	   Kiss: "Je geeft de knuffelbeer een zoen op zijn bruine snuit, en fluistert in zijn oor dat je Maartje terug zal brengen.";
	   
	   Burn:
	     if(TestScope(toorts,player)) {  
	       if(second == toorts || second == nothing) {
	         if(toorts has general) {
		   remove self;
		   move knopen to location;
		   "Bruin brandt als een ketter, onder het uitstoten van walmende rook. Wanneer de vlammen zijn hoofd bereiken kijkt hij je bedroefd en onbegrijpend aan. ~Ik dacht dat je van me hield...~ is de boodschap die zijn knoopogen uitstralen.^^
		   ~Bruin, nee, het spijt me,~ stamel je, en je probeert het vuur uit te maken. Maar je bent te laat, en van de knuffel rest niets anders dan de twee knopen, half gesmolten.";
		 } else {
		   "Nu de toorts gedoofd is kan je er niets meer mee aansteken.";
		 }
	       } else {
	         "Daarmee kan je niets aansteken.";
	       }
	     }
       ],
   has male;
   
   Object knopen "Bruins ogen"
     with name 'ogen' 'knopen' 'knoop' 'gesmolten' 'Bruin^s',
          description 
	     "Twee zwarte knopen, half gesmolten in het verzengende vuur waar je Bruin aan hebt overgeleverd, zijn alles wat deze brave beer aan de wereld heeft nagelaten.",
      has pluralname;
   
   
        
            
   
Object tuin "In de tuin"
  with name 'tuin' 'voortuin' 'buiten' 'beneden',
       description "Ook je voortuin is bedolven onder een dikke laag sneeuw, die alle planten aan het zicht onttrekt. Alleen een paar kale struiken die zich tegen het tuinhek aan schurken steken door de witte deken heen. Achter je leidt de voordeur terug het huis in, terwijl de weg naar het oosten zich door het dorp en het woud heen naar het kasteel van de baron slingert. Vanuit zijn onbereikbare hoogte kijkt de maan verwijtend op je neer. Het uiterste puntje van de kerktoren steekt boven de huizen aan de overkant uit.",
       u_to tuindeur,
       n_to tuindeur,
       in_to tuindeur,
       s_to "Als je naar het zuiden gaat kom je op het dorpsplein uit, bij de kerk. Dat is niet de kant die je op moet om Maartje te bevrijden.",
       w_to "Het westen is precies de verkeerde kant op: die weg zou je het dal uitvoeren, elke stap verder van Maartje en de baron vandaan.",
       e_to bosdeur,
   has light transparent male;

   Object tuinhek "tuinhek" tuin
    class Prop,
     with name 'tuinhek' 'hek' 'opening',
          description "Een laag houten hek scheidt jullie voortuin van de straat. Het tuinpad loopt naar de opening in het hek.",
	  before [;
	    Close, Open: "Het tuinhek loopt niet om de hele tuin heen: er is een opening in uitgespaard.";
	  ],
      has ;
   
   Object tuinpad "tuinpad" tuin
    class Prop,
     with name 'pad' 'tuinpad',
          description "Op het tuinpad ligt maar weinig sneeuw, omdat je het vandaag nog geveegd hebt. Vanaf de voordeur loopt het naar de opening in het tuinhek.",
      has ;
      
Object tuinstruik "struiken" tuin
    class Prop,
     with name 'struik' 'struiken',
          description "De struiken hebben hun bladeren en hun charme allang verloren. Als houten skeletten wachten ze op een nieuw voorjaar.",
      has pluralname;
      
   Object overkant "overkant" tuin
    class Prop,
     with name 'overkant',
          description "De huizen aan de overkant lijken erg op dat van jullie: twee verdiepingen, gemaakt van hout, bedekt met sneeuw. Zo te zien slapen je buren, want uit de ramen komt geen licht.",
      has male;
      
   Object straat "straat" tuin
    class Prop,
     with name 'straat' 'weg' 'smurrie',
          description "De straten liggen vol met de vieze bruine smurrie die achterblijft wanneer voeten en wagenwielen sneeuw met modder vermengen.",
	  before [;
	    Cross: "Je hoeft niet naar de overkant van de weg.";
	  ],
      has male;
      
   Object huis "jouw huis" tuin
    class Prop,
     with pname 'huis' '.x' 'in' '.p' 'woning' '.x' 'in',
          description "Jouw huis is, zoals bijna alle huizen in het dorp, opgetrokken uit hout en in wit, geel en rood geschilderd. Het heeft twee verdiepingen: de slaapkamers liggen op de bovenste, en de huiskamer en keuken op de onderste verdieping. Je werpt een blik door het raam van je slaapkamer, maar Hilde vertoont zich niet om je toch nog uit te zwaaien.",
	  before [;
	    Enter, Go, GoIn: <<Enter tuindeur>>;
	  ],
      has proper;
      
Object tuindeur "deur"
  with pname '.x' 'gele' 'deur' '.p' 'binnen' '.p' 'voordeur' '.p' 'overloop' '.p' 'boven' '.p' 'gang' '.x' 'in',
       description "Afgelopen zomer heb je de voordeur in hard geel geschilderd.",
       found_in tuin,
       door_dir u_to,
       door_to overloop,
       react_before [;
         Climb, Go, GoIn, Enter: if (noun == self || noun == u_obj || noun == overloop || noun == n_obj || noun == in_obj) {
	     if(TuinNaarTrap() == true) return true;
	   };
	 
       ],
   has door scenery male open openable;
   
   
Object brievenbus "brievenbus" tuin
 class Furniture, 
  with name 'brievenbus' 'postbus' 'bus',
       description "Een kleine brievenbus hangt aan de buitenkant van het tuinhek.",
       before [;
         Insert: if(second == self) {
	            if (noun == axe || noun == beer || noun == kleding) {
		      "Dat past niet in de kleine brievenbus.";
		    };  
		  };
       ],
   has male openable ~open container;
   
   Object baron_brief "brief van de baron" brievenbus
     with pname 'brief' '.p' 'brief' 'van' 'de' 'baron' '.p' 'perkament' '.p' 'handtekening',
          description [;
	  print "In sierlijk handschrift is er een bericht op het perkament geschreven:^^";
	  style bold;
	  print "Aan de ouders van Maartje,^
	  ^
	  Bij deze wil ik u mededelen dat uw dochter Maartje op mijn bevel uit uw huis is weggehaald en naar mijn kasteel is vervoerd. Maakt u zich geen zorgen: zij is hier veilig en wordt goed verzorgd. Probeer Maartje niet op te zoeken of bij mij weg te halen; mijn slot is zwaar bewaakt en u zou enkel uw eigen welbevinden op het spel zetten.^
	  ^
	  Ik begrijp dat het moeilijk voor u moet zijn dat u uw dochter bent verloren, en bied mijn excuses aan voor uw leed. U vraagt zich af wat mijn motieven zijn. Welnu, ik houd van haar, en kan niet leven zonder Maartje aan mijn zijde. Bij mij zal ze gelukkig zijn, dat beloof ik u op mijn woord van eer. Ooit zal u inzien dat dit de best mogelijke situatie is.^
	  ^
	  De baron.^^";
	  style roman;
	  "Trillend van woede staar je naar de handtekening onderaan de pagina.";
	  ],
	  before [;
	    Consult: <<Examine self>>;
	    Attack: 
	      move snippers to parent(baron_brief);
	      remove baron_brief;
	      "Woedend verscheur je de brief in tientallen kleine snippertjes. Hoe durft hij! ~Ik houd van haar,~ schrijft hij - vast! De gewetenloze schurk...";
	     Burn:
	      if(TestScope(toorts, player)) {
	       if(second == toorts || second == nothing) {
	         if(toorts has general) {
		   remove self;
		   "Dat voelt goed! Je verast de leugens van de baron, opdat je ze nooit meer zult hoeven lezen.";
		 } else {
		   "Nu de toorts gedoofd is kan je er niets meer mee aansteken.";
		 }
	       } else {
	         "Daarmee kan je niets aansteken.";
	       }
	      }	     
	  ],
      has male;
      
   Object snippers "snippers" baron_brief
    with name 'snippers' 'snipper',
         description "Deze snippers zijn alles wat over is van de afschuwelijke brief van de baron.",
	 before [;
	    Eat: if(actor == player && noun == self) { 
	       print "Je stopt de snippers in je mond, maalt ze met je tanden tot pulp en slikt elke herinnering aan deze infame brief door.^";
	       remove self;
	       return true;
	       };
	    Burn:
	      if(TestScope(toorts, player)) {
	       if(second == toorts || second == nothing) {
	         if(toorts has general) {
		   remove self;
		   "Je strooit de papiersnippers in de vlam van de toorts; als een vlucht dwaze motten vatten ze vlam, dwarrelen brandend naar beneden en zijn al geheel verteerd voordat ze de grond bereikt hebben.";
		 } else {
		   "Nu de toorts gedoofd is kan je er niets meer mee aansteken.";
		 }
	       } else {
	         "Daarmee kan je niets aansteken.";
	       }
	      }
	  ],
     has pluralname;
   
Object axe "bijl" tuin
  with name 'bijl' 'houthakkersbijl',
       description [;
         if(baron.state == 1 || baron.state == 2)
	   "Dit is je belangrijkste gereedschap. Je moet er vele duizenden bomen mee geveld hebben. De bijl is vlijmscherp geslepen, ligt lekker in de hand, en met jouw spieren is het gewicht geen enkel probleem. Waarschijnlijk kan je het hoofd van de baron er in @'e@'en slag mee splijten.";
	 "Dit is je belangrijkste gereedschap. Je moet er vele duizenden bomen mee geveld hebben. De bijl is vlijmscherp geslepen, ligt lekker in de hand, en met jouw spieren is het gewicht geen enkel probleem.";   
       ],
       before [;
       	     Burn: "De bijl zal niet branden; daar is het hout van het handvat veel te hard en stevig voor.";
       ],
   has male;